JavaFX Sintaxis Declarativa

En el post anterior hemos visto un ejemplo sobre cómo realizar un Hello World con JavaFX pero sin entrar en mucho detalle sobre algunas líneas del código, ahora seguiremos con algunos ejemplos más y explicando un poco sobre esto de Sintaxis Declarativa, por ejemplo un objeto puede ser creado con un Objeto Literal. Lo que significa una sintaxis declarativa concisa parecida a javascript, en lugar de explicar "como" realizar algo (el algoritmo, en los lenguajes imperativos), deberemos describir "que" es ese algo. Por ejemplo, en HTML, se declara el contenido de la página, pero no se explica cómo este será mostrado en la pantalla. Ahora veremos algunos ejemplos para aclarar esto.

Iremos desarrollando un ejemplos casi línea por línea para ir notando la simpleza del lenguaje e ir viendo algunos efectos, para este ejemplo usaremos una imagen que la pueden encontrar en el siguiente link ,comencemos.

Paso 1:

import javafx.stage.Stage;

Stage {
    width: 400
    height: 400 
}

con las pocas líneas de arriba ya hemos definido una instancia de un objeto Stage, el cual es necesario para renderizar una ventana.

Paso 2:

import javafx.stage.Stage;
import javafx.scene.Scene;
import javafx.scene.image.ImageView;
import javafx.scene.image.Image;

var image = Image {
    url: "{__DIR__}JavaFX.png"
}

Stage {
    width: 400
    height: 400 
    scene: Scene {
        content: [
            ImageView {
                x: 75
                y: 60
                image: image
            }
        ]
    }
}

aquí hemos complicado un poco la cosa, pero veremos cada detalles, los primeros import de Scene, Image e ImageView son necesarios por los siguiente motivos.
Scene es el objeto el cual nos permite renderizar elementos gráficos dentro de el, el ImageView es el contenedor para una determinada imagen, y por último el Image es la imagen en sí. Si notamos la definición de Scene, vemos que a su propiedad content(Aquí dibujamos los elementos gráficos), hemos agregado una instancia de ImageView y a esta le hemos asignado la imagen previamente cargada en la variable image. Como podrán notar toda la sintaxis es muy simple y siempre nos preocupamos en la declaración de lo que deseamos y no en como generar todo esto.
El código hasta ahora nos generaría una ventana, con la imagen posicionada en el centro, pero nuestra Scene por defecto tiene un color blanco de fondo, si vemos en posts anteriores veremos que podíamos asignar colores en forma de gradientes, pues bueno eso haremos como siguiente paso.

Paso 3:

import javafx.stage.Stage;
import javafx.scene.Scene;
import javafx.scene.image.ImageView;
import javafx.scene.image.Image;
import javafx.scene.paint.LinearGradient;
import javafx.scene.paint.Stop;
import javafx.scene.paint.Color;

/**
 * @author softdesigner
 */

var image = Image {
    url: "{__DIR__}JavaFX.png"
}

Stage {
    width: 400
    height: 400 
    scene: Scene {
        content: [
            ImageView {
                x: 75
                y: 60
                image: image
            }
        ]
        fill: LinearGradient {
            startX : 0.0
            startY : 0.0
            endX : 0.0
            endY : 1.0
            stops: [
                Stop {
                    color : Color.WHITE
                    offset: 0.0
                },
                Stop {
                    color : Color.BLACK
                    offset: 1.0
                }
            ]
        }
    }
}

Si vemos la propiedad fill del objeto Scene, nos damos cuenta que estamos asignando un LinearGradient a esta propiedad, como podemos deducir esto generara un Gradiente linear por medios de las propiedades startX, startY, endX, endY definimos la dirección lineal y por medio de los stops definimos que distintos Stop usar, cada Stop define necesita su propiedad color y su propiedad offset la cual indicada cuando se detendrá ese gradiente.

Muchas veces cuando estamos retocando imágenes o logrando algún efecto se nos plantea la necesidad de lograr un efecto de reflejo sobre el agua o algún material, JavaFX viene con muchas de estas dificultades resueltas ya que brinda diversos efectos para ser aplicados a nuestras imágenes, para ver esto usaremos un efecto de Reflection para lograr reflejar nuestra imagen.

Paso 4:

import javafx.stage.Stage;
import javafx.scene.Scene;
import javafx.scene.image.ImageView;
import javafx.scene.image.Image;
import javafx.scene.paint.LinearGradient;
import javafx.scene.paint.Stop;
import javafx.scene.paint.Color;
import javafx.scene.effect.Reflection;

/**
 * @author softdesigner
 */

var image = Image {
    url: "{__DIR__}JavaFX.png"
}

Stage {
    width: 400
    height: 600
    scene: Scene {
        content: [
            ImageView {
                x: 75
                y: 60
                image: image
                effect: Reflection {
                        fraction: 0.75
                        topOffset: 0.0
                        topOpacity: 0.5
                        bottomOpacity: 0.0
                    }
            }
        ]
        fill: LinearGradient {
            startX : 0.0
            startY : 0.0
            endX : 0.0
            endY : 1.0
            stops: [
                Stop {
                    color : Color.WHITE
                    offset: 0.0
                },
                Stop {
                    color : Color.BLACK
                    offset: 1.0
                }
            ]
        }
    }
}

Ahora tenemos nuestra imagen con un efecto de Reflection, este es asignado al ImageView ya que es el contenedor de la imagen y ahora explicaremos cada propiedad de este efecto.
fraction: Es la fracción que se muestra reflejada en base a la imagen original(Valor porcentual).
topOffset: Es la distancia entre la imagen y el comienzo de su reflejo(Valor libre).
topOpacity: Es la opacidad del comienzo del reflejo(Valor porcentual).
bottomOpacity: Es la opacidad del final del reflejo(Valor porcentual).

Para ir terminando el ejemplo como último detalle, queremos mostrar dos efectos al mismo tiempo, los cuales serán una DropShadow y un efecto Reflection.

Paso 5:

import javafx.stage.Stage;
import javafx.scene.Scene;
import javafx.scene.image.ImageView;
import javafx.scene.image.Image;
import javafx.scene.paint.LinearGradient;
import javafx.scene.paint.Stop;
import javafx.scene.paint.Color;
import javafx.scene.effect.Reflection;
import javafx.scene.effect.DropShadow;

/**
 * @author softdesigner
 */

var image = Image {
    url: "{__DIR__}JavaFX.png"
}

Stage {
    width: 400
    height: 600
    scene: Scene {
        content: [
            ImageView {
                x: 75
                y: 60
                image: image
                effect: Reflection {
                        fraction: 0.75
                        topOffset: 0.0
                        topOpacity: 0.5
                        bottomOpacity: 0.0
                        input: DropShadow {
                                offsetX: 10
                                offsetY: 10
                                color: Color.BLACK
                                radius: 10
                            }
                    }
            }
        ]
        fill: LinearGradient {
            startX : 0.0
            startY : 0.0
            endX : 0.0
            endY : 1.0
            stops: [
                Stop {
                    color : Color.WHITE
                    offset: 0.0
                },
                Stop {
                    color : Color.BLACK
                    offset: 1.0
                }
            ]
        }
    }
}

Si leemos acerca de la propiedad effect del ImageView descubriremos que solo acepta un objeto effect, y aquí nos entra la duda de cómo haremos mas agregar dos efectos al mismo tiempo, para esto casi todos los efectos tiene una propiedad input la cual recibe un effect, así que si nosotros quisiéramos ir encadenando efectos deberíamos hacerlo por medio de esta propiedad, en la parte superior del código se nota que el efecto Reflection recibe un input de un DropShadow, las propiedades del DrowShadow son las siguientes:
offsetX: Cantidad de pixeles sobre el eje x.
offsetY: Cantidad de pixeles sobre el eje y.
color: Color de relleno de la sombra.
radius: Radio del difuminado para la sombra.

Con esto daremos por finalizada esta mínima explicación y demostración sobre la Sintaxis declarativa que ofrece JavaFX y la simplicidad y poder de este lenguaje.
Les dejo un link al ejemplo del proyecto netbeans, luego intentare dejar el jnlp para que lo puedan descargar.

Proyecto
DeclarativeSyntax.rar



Saludos

Leer más...

JavaFX GUI

El Api de JavaFX brinda a los desarrolladores la posibilidad de crear interfaces UI que seran independientes del dispositivo, podemos definir una division entre lo que seria un Common profile y un Desktop profile. El Common profile puede ser usado en aplicaciones de escritorio asi como en aplicaciones para mobiles. En cambio el Desktop profile es espefico de aplicaciones de escritorio.El SDK de JavaFX posee un JavaFX Mobile Emulator en el cual podemos ver como quedan nuestras aplicaciones sobre telefonos mobiles, en algun post veremos como usar esto. Daremos una breve explicacion sobre la separacion de categorias y que paquetes entran en juego, y dejaremos un link a los archivos de ejemplo de Sun.Este post sera una presentacion sobre el mundo JavaFX y dejaremos un videotutorial sobre como crear el indispensable HelloWorld para no fracasar en un nuevo lenguaje.

Contenidos

Common Profile:

• User Interface Elements
• Charts
• Colors
• Shapes
• Fill Styles
• Line Cap and Join Style
• Text
• Transformations
• Layout
  

Desktop Profile:

• Effects
• Cursors
  

Common Profile:

User Interface Elements
Aqui encontraremos todos los componentes para poder crear interfaces de usuario,todos estos componentes se hayan en el paquete javafx.scene.control.

Archivo de ejemplo:
UIControls.fx

Charts
JavaFX ya provee muchos tipos de graficas prefabricadas, estas las podemos encontrar en el paquete javafx.scene.chart veremos una lista de las graficas disponibles:
Graficas de Area
Graficas de Barras
Graficas de Burbujas
Graficas de Lineas
Graficas de Pastel
Graficas de Dispersion

Colors
JavaFX nos provee una clase que se haya en el paquete javafx.scene.paint.Color la cual posee constantes de los colores predefinidos y a su vez metodos especificos para trabajar con ellos.

Archivo de ejemplo:
Colores

Shapes
Los Shapes son las formas basicas que podemos realizar obviamente que mezclandolas entre si podremos obtener otras figuras mas complejas. Esta se encuentra en el paquete javafx.scene.shape.

Archivo de ejemplo:
Shapes

Fill Styles
Los Fill son los tipos de relleno que podemos aplicar cuando pintamos ciertos elementos, a estos le podemos agregar patrones para lograr efecto de pintado ya sea degrade ya sea del tipo radial o lineal, y tambien colores solidos.

Archivo de ejemplo:
Fill Styles

Line Cap and Join Styles
Cuando construimos figuras geometricas muchas veces juntamos lineas y distinos estilos, esto es posible en base a las clases del paquete javafx.scene.shape el cual provee las herramientas necesarias para esto.

Archivo de ejemplo:
Line Cap and Join Styles

Text
Cuando escribimos texto, podemos asignar distintos formatos, estas caracteristicas estan englobadas en el paquete javafx.scene.text, podremos rotar las letras, moverlas de posicion, asignar distinas tipografias, etc.

Archivo de ejemplo:
Text

Transformations
Podemos aplicar diversas transformaciones por ejemplo rotaciones, translaccion de coordenadas, escalado de imagenes, etc.

Archivo de ejemplo:
Transformations

Layout
Los layout nos marcan la distribuccion de los elementos por la ventana, hay diversos tipos y estan almacenados en el paquete javafx.scene.layout.

Archivo de ejemplo:
HBox
VBox

Desktop Profile:

Effects
Podemos aplicar distintos efectos que ya vienen incorporados con JavaFX, estos efectos pueden ser aplicados a los elementos JavaFX UI.

Archivo de ejemplo:
Effects

Cursors
Podemos asignar distintos cursores sobre los elementos de JavaFX.

Archivo de ejemplo:
Cursors

Link General
Les dejo un link con un rar que posee todos los ejemplos de la pagina de Sun, por si el link de algun ejemplo no anda aca estan todos juntos.
Ejemplos

Después de esta pequeña introducción sobre los elementos gráficos y distintas caracterizas incluidas en JavaFX procederemos a hacer el primer ejemplo de nuestro largo camino de aprendizaje, sin más palabras el Hello World!!!
Espero el video tutorial sea entendible ya que este es el primero que hago y hay demasiados errores, espero pueda serle de utilidad y les sirva.

Saludos

Leer más...

Binding And Triggers

Hoy hablaremos de una de las características más poderosas de JavaFX la cual consiste en el binding entre datos, esto nos brinda la posibilidad de vincular dos variables entre si ya sea por el cambio de valor de una, o por la evaluación de una expresión. Además tenemos la posibilidad de asignar triggers que son bloques de códigos los cuales se ejecutan al cambiar el valor de una variable.

Contenidos

• Binding Overview
• Binding and Objects
• Binding and Functions
• Binding with Sequences
• Replace Triggers

Binding Overview
Empezaremos diciendo que para poder realizar el binding entre variables debemos usar la keyword bind, también existe una expresión bound que ahora veremos la cual crea una relación más amplia.

Binding and Objects
Veamos un ejemplo donde creamos un binding entre dos variables.

var x = 0;
def y = bind x;
x = 1;
println(y); // y ahora vale 1
x = 50;
println(y); // y ahora vale 50

Aquí se nota como nosotros solo modificamos los valores de la variable x esto automáticamente se ve reflejado en la variable y.
Ahora veremos un binding parecido pero cuando queremos hacer binding entre objetos.

var myStreet = "1 Main Street";
var myCity = "Santa Clara";
var myState = "CA";
var myZip = "95050";

class Address{
var street;
var city;
var state;
var zip;
}

def address = bind Address {
street: myStreet;
city: myCity;
state: myState;
zip: myZip;
};

println("address.street == {address.street}");
myStreet = "100 Maple Street";
println("address.street == {address.street}");

Aquí definimos la clase Address y luego definimos, 4 variables para iniciar este objeto, al crear nuestro objeto lo hacemos con la palabra bind, esto quiere decir que nuestra variable address siempre tendrá sus atributos actualizado en base a los valores de las variables con cuales fue iniciado.
Si ejecutamos el ejemplo veremos que el resultado es
address.street == 1 Main Street
address.street == 100 Maple Street
Un dato importante que debemos considerar es que con este tipo de binding por cada modificación, se genera un nuevo objeto Address y se asigna nuevamente a la variable.
Otra forma de realizar este binding sin generar un nuevo objeto es de la siguiente manera

var myStreet = "1 Main Street";
var myCity = "Santa Clara";
var myState = "CA";
var myZip = "95050";

class Address{
var street;
var city;
var state;
var zip;
}

def address = Address {
street: bind myStreet;
city: bind myCity;
state: bind myState;
zip: bind myZip;
};

println("address.street == {address.street}");
myStreet = "100 Maple Street";
println("address.street == {address.street}");

La única diferencia es que acá no se hace el bind sobre el objeto sino sobre cada atributo.

Binding and Functions
Aquí es donde entra en juego la keyword bound, no debemos confundir esto con el bind son dos cosas distintas que en combinación nos ofrecen alguna funcionalidad especifica.
Veamos un ejemplo de bind y bound para entender cómo funciona y como usarlo

// Paso 1
var scale = 1.0;

// Paso 2
class Point {
 var x : Number;
 var y : Number;
}

// Paso 3
bound function makePoint(xPos : Number, yPos : Number) : Point {
 Point {
      x: xPos * scale
      y: yPos * scale
 }
}

// Paso 4
var myX = 3.0;
var myY = 3.0;
def pt = bind makePoint(myX, myY);
println(pt.x);

// Paso 5
myX = 10.0;
println(pt.x);

// Paso 6
scale = 2.0;
println(pt.x);

Entendamos este ejemplo paso por paso.
Paso 1:
Aquí definimos una variable del tipo Number y la inicializamos en 1.0

Paso 2:
Definimos la clase Point

Paso 3:
Creamos una función la cual la marcamos con el atributo bound, aquí debemos saber que hay dos tipos de funciones las bound y las not-bound que se comportan de manera distinta si tan con binding sobre una variable.
Las funciones not-bound solo se ejecutan si sus parámetro cambian, en caso contrario las funciones bound siempre se ejecutan

Paso 4:
Creamos las variables las inicializamos y hacemos un bind entre la función y una variable del tipo Point.

Paso 5:
Cambiamos el valor de myX como esta variable fue usada como parámetro de la función con bind se dispara la función y cambia los valores del Point

Paso 6:
Cambiamos el valor de la scale y como esta es una función bound también se vuelve a ejecutar la función y nos cambia los valores de Point
Si ejecutamos el ejemplo el resultado será:
3.0
10.0
20.0
Si sacáramos el bound de la función el resultado sería:
3.0
10.0
10.0

Binding with Sequences
Aquí usaremos un bind entre secuencias pero además usando la expresión for. Tranquilamente podríamos hacer un bind común entre dos secuencias como si fueran variables, pero para ver el poder de esto usaremos una expresión for de la siguiente manera

// Definimos la secuencia 1
var seq1 = [1..10];

// Definimos la secuencia 2, pero con la diferencia que cada ítem será multiplicado por dos
def seq2 = bind for (ítem in seq1) ítem*2;
printSeqs();

function printSeqs() {
 println("First Sequence:");
 for (i in seq1){println(i);}
 println("Second Sequence:");
 for (i in seq2){println(i);}
}

Si ejecutamos el ejemplo el resultado será el siguiente:
First Sequence:
1
2
3
4
5
6
7
8
9
10
Second Sequence:
2
4
6
8
10
12
14
16
18
20

Se nota claramente como la secuencia 2 está relacionada con la secuencia 1,pero además aplica una multiplicación sobre cada ítem, para confirmar el bind vamos a insertar un elemento en la secuencia 1 y este debería estar presente en la secuencia 2

// Definimos la secuencia 1
var seq1 = [1..10];

// Definimos la secuencia 2, pero con la diferencia que cada ítem será multiplicado por dos
def seq2 = bind for (ítem in seq1) ítem*2;
insert 11 into seq1;
printSeqs();

function printSeqs() {
 println("First Sequence:");
 for (i in seq1){println(i);}
 println("Second Sequence:");
 for (i in seq2){println(i);}
}

Si volvemos a correr el ejemplo veremos que ahora la secuencia 1 tiene el ítem 1 y la secuencia 2 tiene el ítem 22.

Replace Triggers
Se le llama Replace Triggers a bloques de códigos que podemos asignar a las variables para que se ejecuten cuando sus valores cambien. Aquí debemos usar la sentencia on replace para poder definir el bloque de código que queremos ejecutar

var password = "foo" on replace oldValue {
 println("\nALERT! Password has changed!");
 println("Old Value: {oldValue}");
 println("New Value: {password}");
};
password = "bar";

Primero creas la variables password donde la inicializamos con el valor "foo"(Supuestamente -Ahora explicare porque pongo esto-) y usamos la sentencia on replace seguido de un nombre a elección del valor anterior y luego definimos el código a ejecutar. al correr el ejemplo veremos lo siguiente

ALERT! Password has changed!
Old Value:
New Value: foo

ALERT! Password has changed!
Old Value: foo
New Value: bar

Vemos que se ejecuta dos veces ya que la variable en un comienzo esta inicializa en Null por eso nuestra inicialización en "foo" es supuesta.

Bueno con esto daremos por finalizada la introducción a las características de JavaFX en lo que sería la parte de scripting, ahora nos dedicaremos a la parte más visual donde empezaremos a usar todos estos conocimientos.

Saludos

Leer más...

Secuencias JavaFX

En esta ocasión hablaremos de las secuencias, estas son una adicción a los tipos básicos de JavaFX, el lenguaje nos provee de una estructura llamada secuencias la cual representa una lista ordenada de objetos (Aunque no sean solamente objetos), cada objeto dentro de la secuencia es llamado ítem. Para declarar una secuencia debemos usar [] y dentro introducir cada ítem separado por comas.

Contenido

• Creating Sequences
• Using Predicates
• Accessing Sequence Items
• Inserting Items into a Sequence
• Deleting Items from a Sequence
• Reversing the Items in a Sequence
• Comparing Sequences
• Using Sequences Slices
  

Creating Sequences
Tenemos varias formas de declarar una secuencia por ejemplo podríamos encerrar los ítem entre [] separados por coma.

def weekDays1 = ["Lunes","Martes"];    // Aquí no definimos el tipo de Dato
def weekDays2: String[] = ["Miercoles","Jueves","Viernes"];   // Aquí informamos el tipo de los Items

Una cualidad importante de las secuencias es que pueden ser construidas en base a otras secuencias, para el ejemplo anterior podríamos hacer realizado la siguiente combinación

// Aquí obtendríamos una secuencia con todos los días
def days = [weekDays1, weekDays2, ["Sabado", "Domingo"]];
println(days) // Print [ Lunes, Martes, Miercoles, Jueves, Viernes, Sabado, Domingo ]
tipo de los Items

Aquí en realidad el compilador aplana las secuencias anteriores para generar la nueva secuencia. JavaFX script también nos provee una forma más simple de trabajar con secuencias aritméticas.
Ejemplo

def nums = [1..100];

Esto crearía una secuencia la cual poseería los números del 1 al 100

Using Predicates
Nos referimos a predicados cuando usamos una expresión booleana para generar una nueva secuencia que sea formada por un sub conjunto de la secuencia original.
Ejemplo:

def nums = [1,2,3,4,5];
def numsGreater = nums[n | n > 2];
println(numsGreater); // Esto imprimiría [3, 4, 5]

Aquí estamos creando una nueva secuencia en base a una existente y un predicado, analicemos mejor este ejemplo, para esto desglosáremos la siguiente sentencia
nums[n | n > 2]

nums // Selecciono la secuencia previa
[ // Abro [ para marcar mi predicado
n // Defino la variable n
| // Se encarga de separar la variable del predicado
n // Indico un criterio de filtrado, que sería propiamente el predicado
] // Cierro el predicado

Accessing Sequence Items
Muchas veces nos vemos en la necesidad de acceder a los ítem que están almacenados en nuestras secuencias y para esto podemos usar los indexes de la secuencia.

def days = ["Lunes", "Martes", "Miercoles", "Jueves", "Viernes", "Sabado", "Domingo"];
println(days[0]);
println(days[1]);
println(days[2]);
println(days[3]);
println(days[4]);
println(days[5]);
println(days[6]);

En este caso no habría problemas porque nosotros conocemos la cantidad de ítems, que hay en nuestra secuencia si nosotros quisiéramos conocer la cantidad de ítems que hay deberíamos usar la palabra reservada sizeof

def days = ["Lunes", "Martes", "Miercoles", "Jueves", "Viernes", "Sabado", "Domingo"];
println(sizeof days);  // Esto imprimiría el numero 7

Inserting Items into a Sequence
Otra palabra reservada del lenguaje es la palabra insert, esta es usada para lograr insertar elemento en una secuencia. Aquí debemos tener en cuenta un dato que no es menor y es que las secuencias realmente son inmutables(Inmutables quiere decir que después de estar creadas nunca se modifican), entonces nosotros en realidad al insertar un ítem en una secuencia en verdad por debajo se crea una nueva secuencia y se reasigna automáticamente, dando la impresión que modificamos la secuencia existente.

// Inicializamos la secuencia con un solo ítem
var days = ["Lunes"];
// Insertamos dos ítem al final de la secuencia
insert "Martes" into days;
insert "Jueves" into days;
// Insertamos un ítem antes que el ítem de la posición 2
insert "Miercoles" before days[2];
// Insertamos un ítem después que el ítem de la posición 3
insert "Viernes" after days[3];

Si usamos posiciones invalidas no sucede nada y los ítem son insertado al final o al comienzo dependiendo el caso, por ejemplo si insertáramos un ítem after days[24] veríamos que realmente se inserta al final de la secuencia o un ítem before days[-1]
este se inserta al comienzo.

Deleting Items from a Sequence
Como ya hemos insertado ítem también debe existir la posibilidad de borrarlos y esto se puede realizar por medio del keyword delete usando en distintas formas

def days = ["Lunes", "Martes", "Miercoles", "Jueves", "Viernes", "Sabado", "Domingo"];
// Borramos el ítem "Lunes"
delete "Lunes" from days;
// Borramos el ítem de la posición 0
delete days[0];
// Borramos todos los ítem, pero la secuencia sigue siendo útil
delete days;

Esto es muy similar a lo anterior, cabe destacar que si elemento marcado o la posición seleccionada para borrar no existen, no se realiza ninguna acción de borrado.

Reversing the Items in a Sequence
Esta técnica nos permite invertir una secuencia en su totalidad usando tan solo la keyword reverse. Veamos un ejemplo para aclarar esto

// Iniciamos la secuencia con los números del 1 al 5
var nums = [1..5];
// Damos vuelta la secuencia
reverse nums;
// Esto imprime [ 1, 2, 3, 4, 5 ]
println(nums);
// Invertimos la secuencia pero ahora si asignamos su resultado
nums = reverse nums;
// Esto imprime [ 5, 4, 3, 2, 1 ]
println(nums);

El ejemplo de arriba nos muestra como las secuencia no se auto asignan su reverse y en este caso debe ser explicito por el programador, no funciona como los delete o insert donde se hace automáticamente.

Comparing Sequences
Para comparar las secuencias se tienen en cuenta dos puntos, el primero su longitud y el segundo la correspondencia entre sus ítem. Al cumplirse estos dos hitos podemos asegurar que las secuencias son iguales.

// Creamos dos secuencias iguales
def seq1 = [1,2,3,4,5];
def seq2 = [1,2,3,4,5];
// Comparamos y esta comparación retorna true
println (seq1 == seq2);

Ahora insertaremos un ítem a la seq2 para lograr que sea diferente que la otra y poder volver a ejecutar la comparación.

// Creamos dos secuencias iguales
var seq1 = [1,2,3,4,5];
var seq2 = [1,2,3,4,5];
// Insertamos un elemento en la seq
insert 6 into seq2;
// Imprimimos la seq2 para comprobar que cambio
println(seq2);
// Comparamos y esta comparación retorna false
println (seq1 == seq2);

Hasta aquí vimos el caso de igualdad y el caso donde la longitud es mayor, ahora nos queda pendiente ver cuando sus ítems tienen otra posición y esto también genera una desigualdad entre secuencias.

// Creamos dos secuencias iguales
var seq1 = [1,2,3,4,5];
var seq2 = [1,2,3,4,5];
// Insertamos un elemento en la seq
seq2 = reverse seq2;
// Imprimimos la seq2 para comprobar que cambio su orden
println(seq2);
// Comparamos y esta comparación retorna false
println (seq1 == seq2);

Aquí cubrimos los 3 casos de comparación entre secuencias, ahora vallamos al último punto

Using Sequences Slices
Antes proceder a explicar las distintas formas de conseguir un slice, deberíamos entender que es un slice, un slice básicamente consiste en una porción de alguna secuencia en base a un criterio o selección, se podría definir un slice como un subconjunto de la secuencia, un slice es una secuencia.
Podemos definir slice de las siguientes maneras
seq[a..b]
seq[a..<b]
seq[a..]
seq[a..<]

En las definiciones de arriba seq seria la secuencia que queremos obtener un slice y a y b los indexes de comienzo y fin, expliquemos cada uno

seq[a..b]

def days = ["Lunes", "Martes", "Miercoles", "Jueves", "Viernes", "Sabado", "Domingo"];
// La nueva secuencia tendría los ítem "Sabado" y "Domingo"
def weekend = days[5..6];

Esta forma de crear un slice incluye ambos indexes

seq[a..<b]

def days = ["Lunes", "Martes", "Miercoles", "Jueves", "Viernes", "Sabado", "Domingo"];
// La nueva secuencia tendría todos los ítem menos "Sabado" y "Domingo"
def weekdays = days[0..<5];

En este caso solo la primer posición es incluida y el otro no.

seq[a..]

def days = ["Lunes", "Martes", "Miercoles", "Jueves", "Viernes", "Sabado", "Domingo"];
// La nueva secuencia tendría los ítem "Sabado" y "Domingo"
def weekend = days[5..];

Aquí estamos definiendo un slice que comience en la posición 5 y que incluya dicha posición hasta el final de la secuencia inclusive.

seq[a..<]

def days = ["Lunes", "Martes", "Miercoles", "Jueves", "Viernes", "Sabado", "Domingo"];
// La nueva secuencia tendría todos los ítem menos el "Domingo"
def days2 = days[0..<]; 

Este tipo de slice es similar al anterior ya que comienza en la primera posición inclusive y va hasta el final de la secuencia pero sin incluir el último elemento

Hasta aquí hemos analizados las distintas acciones y tipos referido a las secuencias ya en el próximo post estaremos analizando el binding y los trigger en JavaFX, me voy despidiendo y espero el post les sea de utilidad

Saludos

Leer más...

Operadores

Los operadores son símbolos especiales que nos brindan los lenguajes para interactuar con uno o dos operando y devolver un resultado, en base al tipo de operador que usemos, veremos si funciona con un solo operando o son ambos requeridos.
Como venimos haciendo hasta ahora presentaremos una lista con los distintos tipos de operadores y luego entraremos en los detalles de cada uno.

Operadores:

• Assignment Operators
• Arithmetic Operators
• Unary Operators
• Equality and Relational Operators
• Conditional Operators
• Type Comparison Operator
  

Assignment Operators
Este es uno de los operadores más comunes que podremos encontrar, básicamente se usa para asignación entre las variables y lo datos que queremos almacenar en ella. Este operador está representado con el símbolo "=".

var example1 = 2;
var example2 = "Test";

En este caso vemos dos asignaciones en el ejemplo 1 guardamos el valor 2 en la variable example1, y en el segundo caso guardamos la cadena de caracteres example2 (En realidad hablamos que guardamos las referencias ya que son objetos, pero no me parece importante para este tema igual quería dejarlo aclarado).

Arithmetic Operators
Los operadores aritméticos son utilizados para los cálculos entre las variables.
+ (additive operator)
- (subtraction operator)
* (multiplication operator)
/ (division operator)
mod (remainder operator)
Estos operadores cubren las 4 operaciones básicas y la operación del resto por medio del modificador mod

Ejemplo

var example = 1 + 2;
println(example);      // example vale 3

example = example - 1;
println(example);      // example vale 2

example = example * 2;
println(example);      // example vale 4

example = example / 2;
println(example);      // example vale 2

example = example + 8;
println(example);      // example vale 10

example = example mod 7;
println(example);      // example vale 3

Unary Operators
Los operadores unarios son aquellos que se puede usar teniendo un solo operando.

example = 0;
example += 1;
println(example); // result vale 1

example -= 1;
println(example); // result vale 0

example = 2;
example *= 5;
println(example); // result vale 10

example /= 2;
println(example); // result vale 5

Equality and Relational Operators
Aquí están los operadores que usamos para las comparaciones y relaciones del tipo, es más grande que, es distinto que, etc.

== // Igual que
!= // Distinto que
> // Mayor que
>= // Mayor o igual que
< // Menor que
<= // Menor o igual que

def num1 = 1;
def num2 = 2; 
println(num1 == num2); // False
println(num1 != num2); // True
println(num1 > num2);  // False
println(num1 >= num2); // False
println(num1 < num2);  // True
println(num1 <= num2); // True

Conditional Operators
En esta sección contamos con dos operadores para las condiciones estos son el operador AND y el operador OR, estos tiene un comportamiento denominado "short-circuiting" lo cual quiere decir que si en una expresión que utilizamos el operador AND y el primer termino es false ya se deja de evaluar el resto, y si usamos un operador OR si el primero termino es verdadero tampoco se evalúa el resto.

def username = "foo";
def password = "bar";

if ((username == "foo") and (password == "bar")) {
println("Test 1: username AND password are correct"); // Test 1: username AND password are correct
}

if ((username == "") and (password == "bar")) {
println("Test 2: username AND password is correct"); // No se ejecuta este código
}

if ((username == "foo") or (password == "bar")) {
println("Test 3: username OR password is correct"); // Test 3: username OR password is correct
}

if ((username == "") or (password == "bar")) {
println("Test 4: username OR password is correct"); // Test 4: username OR password is correct
}

Type Comparison Operator
Este operador es usado para comprobar si un object es instancia de una clase o una subclase en particular. El operador instanceof devuelve true si el objeto es una instancia de la clase especificada. Devuelve false si el objeto no es una instancia de la clase especificada, o si objeto es null.

def str1="Hello";
println(str1 instanceof String); // True

def num = 1031;
println(num instanceof Integer); // False

Bueno esto fue una rápida revisión sobre los operadores en JavaFX, ahora seguiremos viendo secuencias y luego binding y triggers entre funciones para poder irnos introduciendo en la parte grafica de este poderoso lenguaje de scripting.

Saludos hasta la próxima

Leer más...

Modificadores de visibilidad

En este post veremos los distintos tipos de visibilidad que podemos usar para las clases, variables y métodos explicaremos que modificadores aplican a cada uno y sus diferencias, como primer paso comenzaremos nombrando cuales están presente en JavaFX.

Modificadores:

• Default Access

• The package Access Modifier

• The protected Access Modifier

• The public Access Modifier

• The public-read Access Modifier

• The public-init Access Modifier

Default Access
Este modificador es uno que sin saberlo lo usamos en todos los ejemplos anteriores e hicimos mención a él cuando dijimos que se lo conoce como el modificador "script-only", esto quiere decir que cualquier clase, variable o función que no le definamos una visibilidad por defecto podrá ser vista desde cualquier parte del mismo script y de ningún otro lado

The Package Access Modifier
El modificador por package nos permite definir visibilidad de paquete en clases, variables o funciones , ósea nosotros podríamos tener dos archivos .fx los cuales estén el mismo paquete así que podríamos usar las cosas de uno en el otro siempre y cuando hayamos definido su visibilidad en package

Ejemplo:

script1.fx

// Aquí definimos el paquete de este script
package tutorial;

// Definimos la var message con visibilidad de paquete
package var message = "Hello from script1.fx!";

// Definimos la función también con visibilidad de paquete
package function printMessage() {
     println("{message} (in function printMessage)");
}

script2.fx

// Aquí definimos el paquete de este script
package tutorial;

// acedemos a la var message del script1
println(script1.message);

// Llamamos a la función del script1
script1.printMessage();

En el ejemplo se ve como desde un script podemos acceder a las variables o funciones de otro script si están definidos en el mismo paquete y si esas variables o funciones tienen definida una visibilidad de paquete.

The Protected Access Modifier
Con este modificador podremos definir visibilidad en variables y funciones entre el mismo paquete y entre subclases.

Ejemplo:

one.fx

// Aquí definimos el paquete de este script
package tutorial;

public class one {
protected var message = "Hello!";
}

two.fx

style="font-size:100%;">// Importamos el script one
import tutorial.one;

// Como two hereda de one y message esta
// definida como protected puede hacer a su valor
class two extends one {
function printMessage() {
println("Class two says {message}");
}
};
var t = two{};
t.printMessage();

The public Access Modifier
Al usar este modificador estamos dando la posibilidad de acceder ya sea desde cualquier clase o paquete a las clases, variables y funciones que hayan sido expuestas como públicas.
Ejemplo:

One.fx

package tutorial;
public def someMessage = "This is a public script variable, in one.fx";
public class one {
     public var message = "Hello from class one!";
     public function printMessage() {
         println("{message} (in function printMessage)");
}
}

Two.fx

import tutorial.one;
println(one.someMessage);
var o = one{};
println(o.message);
o.printMessage();

The public-read Access Modifier
Bueno los dos últimos modificadores son los más complicados a mi parecer así que prestemos atención como funciona.
Public read nos da la posibilidad que a las variables les digamos que son de solo lectura desde cualquier lado pero funciona para la escritura desde el mismo paquete, pero acá es donde está la trampa nosotros también podríamos definir que sea de solo lectura pública y definir otro scope para la escritura, esto lo logramos de tres maneras.

// Aquí estamos en el caso donde la variable
// es de solo lectura, excepto en el mismo script
public-read var example1 = 'Test';

// Aquí estamos en el caso donde la variable
// es de solo lectura, excepto para los script del mismo paquete
package public-read var example2 = 'Test';

// Aquí estamos en el caso donde la variable
// es de solo lectura, excepto para los script
// del mismo paquete o de subclases
protected public-read var example3 = 'Test';

Me parece que viendo las tres variantes de arriba nos debería quedar una idea clara de cómo funciona este modificador pero si surge alguna duda, no duden en comentar.

The public-init Access Modifier
Este es muy parecido al modificador anterior con la diferencia que este lo usamos para definir donde podemos iniciar nuestra variable.

Ejemplo

Two.fx

import tutorial.one;
var o = one {
     message: "Initialized this variable from a different package!"
}

// No compila, ya que no se definió su escritura
// así que por defecto es el mismo script
o.message = "Changing the message...";
println(o.message);

Bueno con esto hemos echado un vistazo a cada uno, en esta parte no dimos una gran explicación teórica porque creo que los ejemplos reflejan bien los conceptos y además no hay mucho más que decir acerca de estos modificadores.

En el próximo post nos concentraremos en los operadores del lenguaje veremos que son muy similares a Java, pero conviene explicarlo aunque sea brevemente y marcar las diferencias.

Saludos

Leer más...

Clases JavaFX

El API de JavaFX ya nos provee de un gran número de clases que podemos usar en nuestras aplicaciones, sin embargo además podemos definir nuestras propias clases, en esta parte nos concentraremos en definir algunas clases y ver que nuevas variantes nos provee este lenguaje.

Una clase se declara usando la keyword class y el nombre de la clase

class Address {
var street: String;
var city: String;
var state: String;
var zip: String;
}

Como podemos observar aquí estamos definiendo la clase Address la cual consta de 4 variables que por ahora al no definir ningún modificador de visibilidad (Próximo tema ;)) tendrá la visibilidad default que se conoce como "script-only". Esto también aplica para la clase ya que no definimos su modificador de visibilidad y solo podrá ser usada desde el mismo script. Un detalle muy importante es que las clases no poseen constructores la manera de crear una instancia de alguna clase es por medio del nombre de la clase y abrir " { ... } " e inicializar las propiedades que nosotros queramos, podemos imaginar esto como que dentro del closure poseemos un Map de propiedades y ahí asignamos sus valores

def address = Address {
street: "1 Main Street";
city: "Santa Clara";
state: "CA";
zip: "95050";
}

Arriba esta la creación de una instancia de la clase Address, en la cual inicializamos sus distintas propiedades.
Clases abstractas
Al igual que en el lenguaje Java podemos definir una clase como abstracta, recordemos que una clase es abstracta si está definida como abstract class ya sea porque tiene uno o mas métodos(Funciones si nos referimos a JavaFX) , así como si no los tuviera y solo marcara la clase como abstracta.

abstract class Account {
var accountNum: Integer;
var balance: Number;

function getBalance(): Number {
   return balance;
}

function deposit(amount: Number): Void {
   balance += amount;
}

function withdraw(amount: Number): Void {
   balance -= amount;
}
}

Aquí acabamos de definir nuestra clase abstracta que provee toda la funcionalidad necesaria pero por algún motivo hemos decidido marcarla como abstracta, igual eso no nos interesa para el ejemplo, pero es bueno aclarar que esta clase podría ser concreta. Para lograr que una clase herede de otra debemos usar la palabra extends
y luego de esto ya podremos agregar más propiedades o sobre escritura de funciones o lo que necesitemos hacer.

class SimpleAccount extends Account {
   var hasOverDraftProtection: Boolean;

   override function withdraw(amount: Number) : Void {
     if(balance-amount < 0 and hasOverDraftProtection){
         balance = 0;
     } else {
         balance -= amount; // may result in negative account balance!
     }
   }
}

En el ejemplo de SimpleAccount vemos como aplicar herencia, además podemos ver el modificador override que es el encargado de sobrescribir una función, dentro de la misma función que estamos sobrescribiendo vemos como usamos a super para poder acceder a la implementación de la clase padre.

Hasta aquí no hemos encontrado muchas diferencias con Java pero ha llegado el momento de hablar de las clases Mixin.

Clases Mixin
Las clases mixin serian una mezcla de las interfaces Java junto con las clases abstracta ya que están dejan implementar y definir la implementación de las funciones, pero no podemos instanciar clases mixin.

Ejemplo:

package classpkg;

mixin class MyNameMixin {
var firstName = "John";
var lastName = "Doe";
function printName(){
    println("My name is: {firstName} {lastName}");
}
}

mixin class MyAddressMixin {
var address = "1 Main Street, Anytown USA";
function printAddress(){
    println("My address is: {address}");
}
}

class MyContact extends MyNameMixin, MyAddressMixin { }

def myContact = MyContact{};
myContact.printName();
myContact.printAddress();

En este ejemplo estamos definiendo dos clases mixin las cuales tiene propiedades y funciones propias y aunque no se puede crear nuevas instancias de ellas podemos usarla para lograr una herencia múltiple.

Les dejo una lista de reglas sobre las clases:

1. Las clases Mixin no pueden ser instanciadas
2. Las clases Mixin solo pueden heredar de clases Mixin o interfaces
3. Las clases Mixin permiten extender cualquier numero de interfaces o clases Mixin
4. Las clases JavaFX solo pueden heredar de una clase JavaFX ya que está basado en Java

Bueno con esto terminamos este post, el proximo tema sera sobre los modificadores de visibilidad, espero se haya entendido todo y no hayan quedados dudas, cualquier cosa comenten

Saludos

Leer más...

Tipos de datos

Hola como están, seguimos acá investigando JavaFX y empezaremos a ver sus tipos de datos y aprenderemos como trabajar con ellos.
Bien, comencemos

Tipos de datos:

1. String
2. Number and Integer
3. Boolean
4. Duration
5. Void
6. Null

String:
Es el tipo de dato que debemos usar para guardar representación de caracteres, prácticamente funcionan igual que en java pero aquí encontraremos algunas diferencias.

Declaración e inicialización

var cadena1 = 'Cadena 1';
var cadena2 = "Cadena 1";

Como podemos notar aquí esta permitido inicializar o asignar un String ya sea con comillas dobles o comillas simples en cambio en Java solo podíamos hacerlo con comillas dobles. Además si notamos no es necesario decirle que es del tipo String y este tipo ya se asigna automáticamente.

Muchas veces deseamos concatenar distintas variables del tipo String, en JavaFX esto se puede
resolver usando dentro de los " " un closure en el cual se evalúa el String y este es concatenado
en la nuevo String, veamos un ejemplo para aclarar esto

def nombre = 'Joe';
var resultado = "Hello {nombre}";
println(resultado);

Si ejecutamos este código veremos que aparece por consola la frase "Hello Joe" ya que la variable resultado es una referencia al nuevo String que se genera

Nota: Se le llama closure al hecho de que se creen referencias de las variables locales de donde se definió el closure, en el propio closure -Mínima explicación-

def valor = true;
var respuesta = "The answer is {if (valor) "Yes" else "No"}";

Como vemos aquí estamos definiendo un closure con un if que devuelve "Yes" or "No" podríamos pensar esto como una función que recibe como parámetro la variable valor, en cambio aquí simplemente el closure tiene acceso a las referencias desde donde el ha sido definido.

Para no hacerla largo con los String mostraremos el último ejemplo donde veremos como se concatenan dos referencias a String

def frase1 = "This example ";
def frase2 = "joins two strings.";
def fraseFinal = "{frase1}{frase2}";
println(fraseFinal);

Number and Integer:
Estos tipos de datos son los referidos a los tipos numéricos y vamos a distinguir dos tipos los números enteros y los de punto flotante.

def numeroUno = 1.0; // Aquí el compilador infiere el tipo de dato Number
def numeroDos = 1;   // Aquí el compilador infiere el tipo de dato Integer

// Aquí hacemos una declaración explicita
def numeroTres : Number = 1.0;
def numeroCuatro : Integer = 1;

Usualmente se recomienda usar el tipo Integer y dejar el tipo Number solo para
los casos realmente necesarios.

Boolean:
Este valor es igual al tipo Boolean de Java y acepta los valores true/false.

if (isAsleep) {
  wakeUp();
}

El código que ingresemos dentro de "( )" será evaluado en cambio el código ingresado dentro de "{ }" será ejecutado

Duration:
Este es un tipo especial de JavaFX que se encarga de representar una unidad de tiempo

5ms; // 5 milliseconds
10s; // 10 seconds
30m; // 30 minutes
1h;  // 1 hour

Veremos con mayor detenimiento este tipo cuando empecemos a usar Animaciones ya que ahí queremos que en distintos momentos de un Time Line se ejecuten diversas acciones.

Void:
Creo que este ya es conocido por todos, pero diremos que es el tipo que usamos para indicar que una función no retorna ningún valor.

function imprimir() : Void {
  println("Esta funcion no retorna nada!");
}
function imprimir() {
  println("Esta funcion no retorna nada!");
}

Como podemos notar tenemos dos formas que son validas para indicar que la función no retorna ningún valor, ya sea explícitamente con el : Void o implícitamente sin indicar su tipo de retorno

Null:
Este tipo es especial ya que nos permite indicar la falta de un valor normal, cuando declaramos variables están podrían estar referenciando datos no validos.

Estos serian los 6 tipos de datos que se encuentran dentro de JavaFX, ahora solo nos queda empezar a trabajar mas con ellos e ir conociéndolos, ya veremos como son declarados dentro de clases y sus formas de acceso.

Saludos

Leer más...

Comenzando con JavaFX en Windows

Bueno empezaremos con una serie de post acerca de JavaFX. Esta tecnologia sale al mercado para competir contra Flex y Silverlight, todavía está en duda si esta tecnología lograra el lugar que busca, pero me parece un buen momento para empezar a descubrirla.

Partiremos desde lo mas básico, instalando las librerías y buscando que IDE usar hasta que podamos hacer ejemplos donde podamos ir viendo el poder que nos ofrece este nuevo lenguaje de scripting. Para no hacer más largo este primer post paso a comentarles los pasos necesarios para preparar nuestras maquinas para trabajar


Pasos:

• Entraremos al sitio oficial para ver las versiones y hacer las descargas correspondientes
  http://www.javafx.com/
  

• En la página de JavaFX encontraremos diversas cosas que podremos bajarnos, daremos una breve explicación de cada una (JavaFX versión 1.2 al momento de escribir esta nota)

1. JavaFX 1.2 SDK: Al bajar esto estamos bajando el Software Development Kit el cual es un instalador parecido al que ejecutamos al instalar el JDK en nuestras maquinas donde se copiaran las librerías necesarias para desarrollo y además podremos ejecutar los comandos de JavaFX desde la consola de Windows
   
   
2. JavaFX 1.2 Production Suite: Esto es un conjunto de herramientas para los diseñadores que facilita el proceso de incorporación de imágenes en aplicaciones JavaFX
   
   
3. NetBeans IDE 6.5.1 for JavaFX 1.2: Bueno como ya sabrán unos de los IDE más populares para Java en su versión 6.5.1 trae incorporado JavaFX con algunas facilidades para el desarrollo, también hay un plugin para el eclipse pero ciertamente no lo he probado.

Haremos un ejemplo básico para mostrar algunas características básicas y usaremos la consola para compilar y ejecutar nuestro ejemplo, veremos que los archivos no tienen una extensión java sino que poseen su propia extensión .fx igual estos son compilados a bytecode que quedan en archivos .class y luego serán ejecutados por la JVM.
Como primer paso debemos instalar el SDK y probar que la consola nos reconoce lo comandos javafxc y javafx, no debería haber problema alguno con esto pero si alguien tiene algún problema que comente y buscamos el porqué.

Para el ejemplo yo eh creado una carpeta llamada JavaFX donde dejare la siguiente estructura de directorios

C:\JavaFX\maintest\Main.fx

Archivo Main.fx:

package maintest;
// Define Address class.
class Address {
var street: String;
var city: String;
var state: String;
var zip: String;
}

// Create the first Address object instance.
var addressOne = Address {
street: "1 Main Street";
city: "Santa Clara";
state: "CA";
zip: "95050";
}

// Create the second Address object instance.
def addressTwo = Address {
street: "200 Pine Street";
city: "San Francisco";
state: "CA";
zip: "94101";
}

function run(args : String[]) {
for (arg in args) {
  println("Parameters = {arg}");
}
println("Street One = {addressOne.street}");
println("Street Two = {addressTwo.street}");
}

Ahora más adelante explicaremos cada parte del código, este sería nuestro archivo Main.fx ahora lo compilaremos por medio de la consola, abrimos una consola de comandos y nos situaremos en C:\JavaFX.

Compilar paso 1:
Situados en el directorio anteriormente dicho escribimos lo siguiente
javafxc "maintest/Main.fx" esto nos genera los .class necesarios para poder ejecutar el ejemplo

Ejecutar paso 2:
Situados en el mismo directorio anterior escribimos
javafx maintest.Main 9 2 de esta forma estaremos ejecutando nuestro ejemplo pasándole dos parámetros el primero un String que contiene 9 y el segundo un String que contiene el 2.

Explicación básica del código:

Parte 1:

class Address {
var street: String;
var city: String;
var state: String;
var zip: String;
}

Aquí estamos definiendo la clase Address la cual tendrá 4 variables que se indican con la palabra reservada var "elNombreDeLaVariable" : "suTipoDeDato"

Parte 2 y 3:

// Create the first Address object instance.
var addressOne = Address {
street: "1 Main Street";
city: "Santa Clara";
state: "CA";
zip: "95050";
}

// Create the second Address object instance.
def addressTwo = Address {
street: "200 Pine Street";
city: "San Francisco";
state: "CA";
zip: "94101";
}

En ambos casos estamos declarando referencias a objetos del Tipo Address donde usamos { ... } como se usaría un constructor donde inicializamos los distintos valores de la clase, la diferencia importante entre estas dos referencias son que una se declaro con la palabra reservada var y la otra con def. Esto quiero decir que la que se declaro con def seria una referencia del tipo final y no puede cambiar durante la ejecución del script.

Parte 4:

function run(args : String[]) {
for (arg in args) {
  println("Parameters = {arg}");
}
println("Street One = {addressOne.street}");
println("Street Two = {addressTwo.street}");
}

Aquí estamos definiendo la función run que sería el equivalente al main de una clase Java y recibe un array de argumento de longitud variable, en la primer línea iteramos sobre los argumentos y mostramos sus valores en las otras dos imprimimos los valores de las distintas direcciones para lograr imprimirlo se usa {addressOne.street} de manera que fuera un closure.

Bueno esto fue todo por este post por cualquier duda que posiblemente haya espero los comentarios y en qué forma se podría mejorar el post.
En próximas entradas veremos los tipos de datos de JavaFX así como en más detalles sus distintas características.

Saludos

Leer más...